WesPipe/tasks/BQSR.wdl

task BQSR {
  
  File ref_dir
  File dbsnp_dir
  File dbmills_dir
  
  String sample
  String SENTIEON_LICENSE
  String fasta
  String dbsnp
  String db_mills
  File deduped_bam
  File deduped_bam_index
  String docker
  String cluster_config
  String disk_size

  File? regions
  Int? interval_padding
  
  command <<<
    set -o pipefail
    set -e
    export SENTIEON_LICENSE=${SENTIEON_LICENSE}
    nt=$(nproc)

    if [ ${regions} ]; then
      INTERVAL="--interval ${regions} --interval_padding ${interval_padding}"
    else
      INTERVAL=""
    fi

    sentieon driver -t $nt \
    -r ${ref_dir}/${fasta} -i ${deduped_bam} \
    $INTERVAL \
    --algo QualCal \
    -k ${dbsnp_dir}/${dbsnp} -k ${dbmills_dir}/${db_mills} \
    ${sample}_recal_data.table

    sentieon driver -t $nt \
    -r ${ref_dir}/${fasta} -i ${deduped_bam} -q ${sample}_recal_data.table \
    --algo QualCal -k ${dbsnp_dir}/${dbsnp} -k ${dbmills_dir}/${db_mills} \
    ${sample}_recal_data.table.post --algo ReadWriter ${sample}.sorted.deduped.recaled.bam

    sentieon driver -t $nt --algo QualCal \
    --plot --before ${sample}_recal_data.table --after ${sample}_recal_data.table.post ${sample}_recal_data.csv

    sentieon plot bqsr -o ${sample}_bqsrreport.pdf ${sample}_recal_data.csv
  >>>

  runtime {
    docker: docker
    cluster: cluster_config
    systemDisk: "cloud_ssd 40"
    dataDisk: "cloud_ssd " + disk_size + " /cromwell_root/"
  }

  output {
    File recal_table = "${sample}_recal_data.table"
    File recal_post = "${sample}_recal_data.table.post"
    File recaled_bam = "${sample}.sorted.deduped.recaled.bam"
    File recaled_bam_index = "${sample}.sorted.deduped.recaled.bam.bai"
    File recal_csv = "${sample}_recal_data.csv"
    File bqsrreport_pdf = "${sample}_bqsrreport.pdf"
  }
}