ANNOVAR/tasks/annovar.wdl

task annovar {

  File vcf
  String basename = basename(vcf,".vcf")
  String hg
  File annovar_database
  String docker
  String cluster_config
  String disk_size


  command <<<
    set -o pipefail
    set -e
    nt=$(nproc)

    if [ ${hg} == "hg38" ]; then
    /installations/annovar/table_annovar.pl ${vcf} \
    ${annovar_database} -buildver ${hg} \
    -out ${basename} -remove \
    -protocol refGene,cytoBand,genomicSuperDups,ljb26_all,dbnsfp35c,intervar_20180118,cosmic70,exac03,gnomad211_exome,clinvar_20210501 \
    -operation g,r,r,f,f,f,f,f,f,f \
    -nastring . -vcfinput -thread $nt
    fi

    if [ ${hg} == "hg19" ]; then
    /installations/annovar/table_annovar.pl ${vcf} \
    ${annovar_database} -buildver ${hg} \
    -out ${basename} -remove \
    -protocol refGene,cytoBand,genomicSuperDups,ljb26_all,snp138,cosmic78,intervar_20170202,popfreq_all_20150413,clinvar_20190305 \
    -operation g,r,r,f,f,f,f,f,f \
    -nastring . -vcfinput -thread $nt
    fi
  >>>
  
  runtime {
    docker: docker
    cluster: cluster_config
    systemDisk: "cloud_ssd 40"
    dataDisk: "cloud_ssd " + disk_size + " /cromwell_root/"
  }

  output {
    File avinput = "${basename}.avinput"
    File multianno_txt = "${basename}.${hg}_multianno.txt"
    File multianno_vcf = "${basename}.${hg}_multianno.vcf"
  }
}