variant-calling/tasks/TNscope.wdl

task TNscope {
  
  String sample
  String SENTIEON_INSTALL_DIR
  String SENTIEON_LICENSE
  File tumor_deduped_bam
  File tumor_deduped_bam_index
  File tumor_recal_table
  File normal_deduped_bam
  File normal_deduped_bam_index
  File normal_recal_table
  String tumor_name
  String normal_name

  File ref_dir
  String fasta
  File dbsnp_dir
  String dbsnp
  File? regions
  Int? interval_padding
  File? pon_vcf

  String docker
  String cluster_config	
  String disk_size

  command <<<
    set -o pipefail
    set -e
    export SENTIEON_LICENSE=${SENTIEON_LICENSE}
    nt=$(nproc)

    if [ ${regions} ]; then
      INTERVAL="--interval ${regions} --interval_padding ${interval_padding}"
    else
      INTERVAL=""
    fi

    if [ ${pon_vcf} ]; then
      PON="--pon ${pon_vcf}"
      ${SENTIEON_INSTALL_DIR}/bin/sentieon util vcfindex ${pon_vcf}
    else
      PON=""
    fi

    ${SENTIEON_INSTALL_DIR}/bin/sentieon driver -t $nt \
    -r ${ref_dir}/${fasta} $INTERVAL \
    -i ${tumor_deduped_bam} -q ${tumor_recal_table} \
    -i ${normal_deduped_bam} -q ${normal_recal_table} \
    --algo TNscope \
    --tumor_sample ${tumor_name} --normal_sample ${normal_name} \
    --dbsnp ${dbsnp_dir}/${dbsnp} \
    $PON \
    ${sample}.TNscope.TN.vcf
  >>>

  runtime {
    docker: docker
    cluster: cluster_config
    systemDisk: "cloud_ssd 40"
    dataDisk: "cloud_ssd " + disk_size + " /cromwell_root/"
  }

  output {
    File TNscope_vcf= "${sample}.TNscope.TN.vcf"
    File TNscope_vcf_index = "${sample}.TNscope.TN.vcf.idx"
  }
}